Краткое описание

Лицензирование

Этот файл доступен по лицензии Creative Commons Attribution-Share Alike 2.5 Generic Вы можете свободно: делиться произведением – копировать, распространять и передавать данное произведение создавать производные – переделывать данное произведение При соблюдении следующих условий: атрибуция – Вы должны указать авторство, предоставить ссылку на лицензию и указать, внёс ли автор какие-либо изменения. Это можно сделать любым разумным способом, но не создавая впечатление, что лицензиат поддерживает вас или использование вами данного произведения. распространение на тех же условиях – Если вы изменяете, преобразуете или создаёте иное произведение на основе данного, то обязаны использовать лицензию исходного произведения или лицензию, совместимую с исходной. https://creativecommons.org/licenses/by-sa/2.5CC BY-SA 2.5 Creative Commons Attribution-Share Alike 2.5 truetrue

If you use this image, you have to credit this: Image by א (Aleph), http://commons.wikimedia.org

Wenn Sie dieses Bild verwenden, müssen Sie folgendes angeben: Bild von א (Aleph), http://commons.wikimedia.org

Gnuplot Script

# #############################################################
#
# This file was created by א and may 
# only be used under the terms of the 
# Creative-Commons-License CC-BY-SA-2.5 
# with apropriate attribution. 
#
# You MUST credit this: א (Aleph), http://commons.wikimedia.org
#
# #############################################################
# Gnuplot code as follows:
reset
set terminal svg enhanced size 1200 600 fsize 20 fname "Arial"
set output "gaussian_beam_german.svg"
set multiplot
# set key off
# Variables used for gaussian beam
w0 = 2.0
z0 = 4.0
# Configure coordinate system
# set xzeroaxis linetype rgb "black"
# set yzeroaxis linetype rgb "black"
unset border
unset tics
set xtics axis mirror ("- z_0" -z0, "+ z_0" z0) offset 0,0.5
set xrange [-20:20]
set yrange [-12:10]
set label "z" at 18.5,-0.5
set label "r" at 0.5,8.5
# Arrows along the axes
set style arrow 2 filled size 1,10
set arrow arrowstyle 2 from -20,0 to 20,0
set arrow arrowstyle 2 from 0,-10 to 0,10
# Function for gaussian beam
w(z) = w0*sqrt(1+(z/z0)**2)
# Function for asymptotes
a(z) = w0/z0 * z
# Arrow for w0
set style arrow 1 heads filled size 0.5,10 front
set arrow arrowstyle 1 from 0,0 to 0,w0
set label "w_0" at 0.25,1
# Arrow for w(z)
z1 = 12
set arrow arrowstyle 1 from -z1,0 to -z1,w(z1)
set label "w(z)" at -z1+0.25,0.5*w(z1)
# Lines at the end of b
set style arrow 3 nohead lt rgb "grey"
set arrow arrowstyle 3 from z0,0 to z0,4
set arrow arrowstyle 3 from -z0,0 to -z0,4
# Arrow for b
set arrow arrowstyle 1 from -z0,w(z0)+1 to z0,w(z0)+1
set label "b" at -1,w(z0)+1.5
# Arrow for w(z0)
set arrow arrowstyle 1 from -z0,0 to -z0,w(z0)
set label "√2·w_0" at -z0-2.5,0.5*w(z0)
k=-0.5 #Variable needed for wavefronts
R(k) = k*(1+(z0/k)**2) # Radius of wavefronts
zM(k) = k - R(k) # Centre of wavefronts
# This is where the Wavefronts touch the border of the beam:
zQ(k) = zM(k)/(1.0 + (w0/z0)**2) + sqrt((zM(k)/(1.0+(w0/z0)**2))**2 - (w0**2+zM(k)**2-R(k)**2)/(1.0+(w0/z0)**2))
k = k+3 # k is the point at which the Wavefront is drawn.
W(z) = z >= zQ(k) ? sqrt(R(k)**2-(z-zM(k))**2) : 1/0 # Wavefront ist plotted for k >= zQ only.
set dummy z
set key at 14,-11
# Plot wavefronts with many samples
set samples 100000
plot W(z) lt rgb "black" title "Wellenfronten", -W(z) lt rgb "black" notitle
k = k+3
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+3
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+3
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+3
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+3
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+3
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
set samples 1000
# Plot grey lines
plot w0 linetype rgb "grey" linewidth 1 notitle, -w0 linetype rgb "grey" linewidth 1 notitle, a(z) linetype rgb "grey" linewidth 1 notitle, -a(z) linetype rgb "grey" linewidth 1 notitle
# Plot borders of the beam
set key at 14,-10
plot w(z) lt rgb "red" linewidth 3 title "Begrenzung des Gaußstrahls", -w(z) linetype rgb "red" linewidth 3 notitle
# Angle Θ
set label "Θ" at -1.75,0.4
set polar
theta = atan(w0/z0)
set trange [-pi-theta:-pi+theta]
plot 2 lt rgb "black" notitle
# Undo everything
reset